[应求][HACK]全触摸汉化版灵光ROM

tring

这次灵光虽然完全没有用到触摸屏~但是奇怪的是游戏并没有封掉触摸功能~估计可能本来是想支持触摸的~但是出于当时ASH的值崩~所以直接临时取消了~……
所以这次就单纯的修改难度上来说可以说和RY传说不是一个档次的~
因此~这次俺就将主要精力全部集中在代码的优化上~在这方面狠下了点功夫~
记得上次RY传说的插入代码~就手写部分~俺前后就花了十来分钟就搞定了~但是这次灵光的足足花了我一天的时间来写~……
另外~出于有人反映上次RY传说会偶尔出现帖图错误~而且这次我最初完成的版本的灵光也是会出现帖图错误~于是研究了一下~发现主要原因应该在于插入代码过大~难免覆盖掉有用信息~导致帖图出错~
于是这次俺又研究了一下代码载入内存的过程~最后终于研究出了~不必将代码插入空中~也可以顺利载入到内存中的方法~
于是~理论上来说~这次的修改版ROM应该是能将副作用降低到最低的~（当然~实际上是否如此俺就说不准了~……）

好了~功能说明：
操作分成2种模式~

1，普通模式~如同RY传说设定的那个操作~不过按键稍微改了下~
L  |  UP  |  R   
LE|  A  |  RI  
B  |  DO |  X  

2，战斗模式
对应下屏显示~所有显示出来的按键都能点~
另外点地图对应移动~支持8方向移动~

另外~顺便提一句~因为看汉化版插的广告不爽~所以顺便就把广告给去掉了~……

下载链接：
纳米盘：soma_by_touch.7z.

tring

惯例~放上代码的源码~

@ from 203f270
@ b 022278
@ to 20c7c58
@ b fddd4a

S:

@ r3为key值 r2为keyXY值
ldrh r2,[r1]
stmdb r13!,{r0,r1,r4-r12,r14}

@ 判定触摸
ldr r0,ab1
ldrb r1,[r0]
cmp r1,#0x01
bne ed1

@ 定位触摸坐标到(r4,r5)
ldr r0,ab2
ldrh r1,[r0]
mov r4,r1,lsr #0x4
and r4,#0xff
ldr r0,ab3
ldrb r5,[r0]

@ 触摸识别循环 r6读取索引 r7读取基指
ldr r0,adrScr
ldr r1,cntScr
ldr r0,[r0]
cmp r0,r1
adreq r7,btmode
adrne r7,n9mode
ldrb r6,[r7]
mov r0,#0x5
mul r6,r0,r6

ML:
@ 触摸识别 r8跳转索引 r9范围坐标指针
ldrb r8,[r7,r6]
sub r6,#0x4
add r9,r7,r6
@ 区域定位
ldrb r0,[r9]
cmp r4,r0
bcc EL
ldrb r0,[r9,#0x1]
cmp r5,r0
bcc EL
ldrb r0,[r9,#0x2]
cmp r4,r0
bcs EL
ldrb r0,[r9,#0x3]
cmp r5,r0
bcs EL
@ 索引跳转
and r1,r8,#0xf0
cmp r1,#0x10
bne N1
@
and r1,r8,#0xf
adr r0,cmA
ldr r1,[r0,r1,lsl #0x2]
and r3,r1
b ed1
N1:
cmp r1,#0x20
bne N2
@
and r1,r8,#0xf
adr r0,cmX
ldr r1,[r0,r1,lsl #0x2]
and r2,r1
b ed1
N2:
cmp r1,#0x0
bne EL
bl PadPro
b ed1

EL:
cmp r6,#1
sub r6,#1
bne ML

@ 返回
ed1:
ldmia r13!,{r0,r1,r4-r12,r14}
b go_back

@方向板处理 r10指令索引
PadPro:
cmp r4,#0x4b
sub r4,#0x4b
movcs r0,#0x0
movcc r0,#0x2
rsbcc r4,#0x0
cmp r5,#0x99
sub r5,#0x99
addcc r0,#0x1
rsbcc r5,#0x0
mov r10,r0
@
cmp r4,r5
sub r11,r4,r5
rsbcc r11,#0x0
ldr r0,sqr2
mul r1,r11,r0
mov r11,#0x2
ldr r0,sqr1
mul r0,r4,r0
cmp r1,r0
bcs T1
ldr r0,sqr1
mul r0,r5,r0
cmp r1,r0
bcc T2
T1:
cmp r4,r5
movcs r11,#0x1
movcc r11,#0x0
T2:
add r10,r11,r10,lsl #0x2
adr r0,PadCmd
ldrb r0,[r0,r10]
add r0,#0x300
and r3,r0
bx lr

ab1: .long 0x027fffad
ab2: .long 0x027fffab
ab3: .long 0x027fffac
adrScr: .long 0x020e67c8
cntScr: .long 0x40400070
x1: .byte 0x50
x2: .byte 0xb0
y1: .byte 0x50
y2: .byte 0xb0
cmA: .int 0x03fe
cmB: .int 0x03fd
cmL: .int 0x01ff
cmR: .int 0x02ff
cmLe: .int 0x03df
cmRi: .int 0x03ef
cmUp: .int 0x03bf
cmDo: .int 0x037f
cmSt: .int 0x03f7
cmSe: .int 0x03fb
cmX: .int 0x2800
cmY: .int 0x2400

n9mode:
.byte 0x9
.long 0x50500000
.byte 0x12
.long 0x50b00050
.byte 0x16
.long 0x50ff00b0
.byte 0x13
.long 0xb0505000
.byte 0x14
.long 0xb0b05050
.byte 0x10
.long 0xb0ff50b0
.byte 0x15
.long 0xff50b000
.byte 0x11
.long 0xffb0b050
.byte 0x17
.long 0xffffb0b0
.byte 0x20
.byte 0x00
.byte 0x00

btmode:
.byte 0x9
.long 0x5eff4289
.byte 0x20
.long 0x85ff6a89
.byte 0x21
.long 0xacff9089
.byte 0x10
.long 0xd3ffb789
.byte 0x11
.long 0x1b4b0000
.byte 0x12
.long 0x1bff00ae
.byte 0x13
.long 0xff7fdd28
.byte 0x19
.long 0xffcedd9a
.byte 0x18
.long 0xdc894200
.byte 0x03
.byte 0x00
.byte 0x00

sqr2:.long 3
sqr1:.long 2

PadCmd:
.long 0x006fef7f
.long 0x00afefbf
.long 0x005fdf7f
.long 0x009fdfbf

tring

哦~对了~忘记说了~
本ROM是应某同学所要求的~
俺自己因为卡里最近塞了那个2G的13岁职业LOLI~所以么空间了~
因此没实卡测试过~

乃如果用的发现有啥严重BUG（不严重就算了哈哈）~就这报错就好了~

kennyp

大大簡直..太神了..

那麼就是說遊戲原本是支持觸摸的才能為該遊戲做成這個補丁嗎?

tring

下面是引用kennyp于2008-06-04 04:37发表的:
大大簡直..太神了..

那麼就是說遊戲原本是支持觸摸的才能為該遊戲做成這個補丁嗎?

不……就算游戏压根不支持触摸~也有方法能强制使用触摸屏~
这个教程有将近一半篇幅用来讨论如何为不支持触摸的游戏加入此功能~
https://bbs.luryl.com/viewthread.php?tid=904672&fpage=1

俺这里只是说~灵光并没有屏蔽掉触摸功能~所以改起来可以说基本么啥难度而已~……

风间隼人

啥都不说了..........人才呐..........

(忍)

楼主你狠...虽然说一般没什么用..不过对部分按键有问题的玩家来说那可是神了

saiiscool

很无敌的DIY 佩服啊

kennyp

教程實在是太深了...................................

那麼有可能把原本只有觸摸的轉成按鍵嗎?

實在有不少因為只有觸摸的好遊戲被毀了啊..

则卷小饼！

这游戏，貌似用触控就...
还是按键舒服...